Was Notepad kann, ...

[d'r Bastler]

... kann Word auch, wenn auch ein wenig komplizierter.

Moin allerseits,
nebenan gab es die nette Aufgabe für ein -von mehreren Personen fortlaufend geführtes- Protokoll eine laufende Nummer der Einträge zu generieren. Der Windows-Dino Notepad.exe kann das zumindest aktuelles Datum und Zeit, wenn man einfach nur einen Punkt als erster Zeichen liegen lässt.

Hier geht's ein bisschen weiter: Beim Öffnen der Datei werden Benutzername: die lfd.Nr. des Tages, die Uhrzeit hh:mm mit abschließendem Zeilenumbruch eingefügt und der Cursor am Beginn des neuen Eintrags platziert. Vorheriger Text wird nach unten verschoben.

Der Code gehört in ein allg. Modul des aktuellen Dokuments und wird in ThisDocument mit

Code: Alles auswählen

Private Sub Document_Open()
    Call LastEdit
End Sub

aufgerufen.

Code: Alles auswählen

Public Sub LastEdit()
Dim iDay As Integer, sDay As String, rng As Range

iDay = DateDiff("d", DateSerial(Year(Date), 1, 1), Date) + 1
    
    sDay = iDay
    If iDay < 10 Then
        sDay = "00" & iDay
    ElseIf iDay < 100 Then
        sDay = "0" & iDay
    End If
    
sDay = Environ$("USERNAME") & ": " & sDay & "-" & Format(Time, "hh:mm")
    
Set rng = ActiveDocument.Range(0, 0)
With rng
    .InsertBefore sDay & vbCrLf & vbCrLf
    .MoveEnd Unit:=wdParagraph, Count:=1
End With

With ActiveDocument.Paragraphs(2).Range
    .Collapse Direction:=wdCollapseStart
    .Select
End With

End Sub

Ergebnis in der ersten Zeile d'r Bastler: 169-12:07

Wer nur lesen will, tut das ohne das Dokument am Ende zu speichern. Wer ergänzen will, speichert.

Viel Spaß damit!

[knobbi38]

Hallo,

reichen da nicht die Feldfunktionen SaveDate und LastSaveBy ?

Gruß Knobbi38

[d'r Bastler]

Moin Knobbi,

LastSavedBy und SaveDate beziehen sich auf den jeweils vorherigen Stand.

Hier geht es aber darum den aktuellen Doc-Öffner mit einem Zeitstempel in die erste Zeile zu schreiben und damit Gelegenheit zu geben quasi direkt unter seiner Signatur den Text zu ergänzen. Die beiden Feldfunktionen sind da noch nicht aktualisiert.

Will einer nur lesen, steigt er einfach wieder aus.

Mein Code oben ist dennoch ein Schnellschuss mit -wie heißt es so schön?- Optimierungspotential Eine Version mit Userform und eleganterem Code für z.B. die führenden Nullen bei der Tagesnr. usw.

Das gibt's dann morgen

Schönen Amnd noch!

[knobbi38]

Hallo d'r Bastler,

hier mal ein etwas andere Ansatz. Die Info wird beim Öffnen jeweils aktualisiert und als "Document Variable" bereitgestellt, man könnte ebenso auch eine "Custom Document Property" dafür verwenden. Der Vorteil dabei ist, daß diese Information jetzt per Feld überall im Dokument angezeigt werden kann, ohne dass die Einfügestelle im Code festgelegt werden muß.

Code: Alles auswählen

' Klasse: ThisDocument

Option Explicit

Private Sub Document_Open()
  Dim strDocValue As String
  
  Const DOC_VAR_NAME As String = "EditInfo"
  
  strDocValue = _
      GetUserFullName & ";" _
      & Format$(DatePart("y", Date), "000\-") _
      & Format$(Time(), "hh:nn")
  
  On Error Resume Next
  Me.Variables(DOC_VAR_NAME).Delete
  On Error GoTo 0
  
  Me.Variables.Add DOC_VAR_NAME, strDocValue
  Me.Fields.Update
End Sub

Angezeigt wird übrigens der FullName des Benutzers (GetUserFullName()) und nicht nur der Loginname, der könnte ja manchmal auch kryptisch sein.

Hier noch eine vereinfachte Funktion, welche den Tag des Jahres als numerischen Wert zurück gibt:

Code: Alles auswählen

Public Function DayOfYear(Optional ByVal Value As Date) As Long
  If Int(Value) = 0 Then Value = Date
  DayOfYear = DatePart("y", Value)
End Function

Gruß Knobbi38