nachgestellte Kommentare

[d'r Bastler]

Moin allerseits,

wer viel VBAastelt und dies anderen zur Verfügung stellt, kommentiert auch viel .. manchmal zuviel

Hier ein paar Zeilen (in ein Modul), mit denen man nachgestellte Kommentare aufräumen kann. Mit etwas Hirnschmalz klappt das dann auch mit Kommentarzeilen.

Code: Alles auswählen

Sub DeletePostComments()
Dim mdl As Object
Dim sCode As String
Dim i As Integer, iPost As Integer, iPre As Integer, iPos As Integer

Set mdl = ThisWorkbook.VBProject.VBComponents("Modul1").CodeModule 'ANPASSEN

    For i = 1 To mdl.CountOfLines
        sCode = mdl.Lines(i, 1)
        iPos = InStr(sCode, "'")
        
        If iPos > 1 Then
            sCode = Left(sCode, iPos - 1)
            mdl.ReplaceLine i, sCode
            iPost = iPost + 1
        End If
        If iPos = 1 Then
            iPre = iPre + 1
        End If
    Next i
    
    MsgBox iPost & " nachgestellte Kommentare wurden entfernt." & vbNewLine & iPre & " Anfangskommentar sind noch vorhanden.", vbInformation
End Sub

Viel Spaß damit!

[knobbi38]

Hallo d'r Bastler,

leider reicht dieser Code

Code: Alles auswählen

iPos = InStr(sCode, "'")

nicht aus, um den Beginn eines Kommentars in einer Zeile zu erkennen. Ein reguläres "'" wird z.B. sehr häufig in SQL-Strings benötigt, da dort Feldinhalte vom Typ Text immer in Hochkommas stehen.
Wenn du Kommentare erkennen möchtest, muß geprüft werden, ob das Hochkomma z.B. in Strings steht oder wirklich als Symbol verwendet wird. Um das Parsen der Codezeile im weitesten Sinne kommt man also nicht herum, leider.

Gruß Knobbi38

[knobbi38]

Nachtrag:

um einen Kommentar einfacher zu identifizieren, könnte man auch mit diesem regulären Ausdruck arbeiten:

Code: Alles auswählen

^(.*)\ '([^']*)$

Dann entsprechen die Backreferences $1 dem Code vor dem Kommentar und $2 dem Kommentar selber.

zum Testen kann man diese Site verwenden:
https://regex101.com/r/gnUb9V/2


HTH
Knobbi38

[d'r Bastler]

Moin Knobbi,

Deine Ergänzung berücksichtigt (natürlich mal wieder ) alle möglichen Abgründe der Syntax. Nachdem in meinen Codes (bisher) keine SQL-Statements vorkommen, aber z.B. maskierte Hochkommata im Zusammenhang mit Strings, muss ich zugeben, das nicht berücksichtigt zu haben.

Fehler konnte ich bisher dadurch vermeiden, dass ich meine Kommentare oft einfach durch '# einleite und den Instr entsprechend anpasse. Für Zeilen im Code, die ich mir z.B. als ToDo oder Debug markieren möchte stelle dann einfach ein '### o.Ä. voran und kann sie so auch in umfangreichen Moduln schnell finden. Mein Vorschlag lässt sich dadurch natürlich beliebig individualisieren.

Liebe Grüße

[knobbi38]

Hallo d'r Bastler,

es geht doch nichts über eine gewisse Code-Disziplin

Hier mal ein Beispiel für eine Funktion zum Abschneiden des Kommentars am Ende einer Codezeile

Code: Alles auswählen

Public Function StripComment(ByVal SourceText As String) As String
  Static regEx As Object
  
  If regEx Is Nothing Then
    Set regEx = CreateObject("vbscript.regexp")
    regEx.Global = True: regEx.MultiLine = True
    regEx.Pattern = "(\s+'[^']*)$"
  End If
  
  If regEx.Test(SourceText) Then
    StripComment = regEx.Replace(SourceText, "")
  End If
  
  If Len(StripComment) = 0 Then
    StripComment = SourceText
  End If
End Function

Das reguläre Pattern isr dabei etwas modifiziert, damit führende Einrückungen erhalten bleiben, aber Whitespaces zwischen Codeline und Beginn des Kommentars mit gelöscht werden.

Gruß Knobbi38